(**      UNITPRICECHART - GENERATE A UNIT-PRICE CHART.
*
*        ANDY MICKEL    76/09/07, 80/06/22.
*
*        COPYRIGHT (C)  1980.
*)

(*       A UNIT-PRICE CHART IS A TABLE OF COST PER UNIT OF MEASURE--
*        REGARDLESS OF WHAT THAT UNIT IS--SO THAT YOU CAN COMPARE
*        PRICES OF MERCHANDISE WHICH IS AVAILABLE IN DIFFERENT QUANTITIES.
*)

PROGRAM UNITPRICECHART(OUTPUT);

  CONST
     DOLLARS = 0.01;
     PRICEMAX = 500 (* FIVE DOLLARS *);
     PAGEENTRIES = 50;
     ENTRIESPERLINE = 22;

  VAR
     UNIT: 1 .. ENTRIESPERLINE;
     LINE: 1 .. PAGEENTRIES;
     PRICE: 0 .. PRICEMAX;
     PAGES: INTEGER;

  PROCEDURE WRITEHEADING;

    VAR
       I: INTEGER;

  BEGIN
     PAGE(OUTPUT);
     WRITELN;
     WRITELN('UNIT PRICE CHART IN CENTS PER UNIT' :80);
     WRITELN;
     WRITELN('UNITS' :12);
     WRITE(' ' :6);
     FOR I := 2 TO ENTRIESPERLINE DO
       WRITE(I :6);
     WRITELN;
     WRITELN('PRICE' :6);
     WRITELN
  END (*WRITEHEADING*) ;

BEGIN
   PRICE := 0;
   FOR PAGES := 1 TO PRICEMAX DIV PAGEENTRIES DO
   BEGIN
      WRITEHEADING;
      FOR LINE := 1 TO PAGEENTRIES DO
      BEGIN
         PRICE := PRICE + 1;
         WRITE(PRICE * DOLLARS :6:2);
         FOR UNIT := 2 TO ENTRIESPERLINE DO
            WRITE(PRICE/UNIT :6:1);
         WRITELN;
         IF (PRICE MOD 5 = 0) THEN
            WRITELN
      END
   END
END.
: